Merge pull request #781 from sumnerevans/standard-fixer

Added fixer for Standard linter

autoload/ale/fix/registry.vim

@@ -62,6 +62,11 @@ let s:default_registry = {
 \       'suggested_filetypes': ['ruby'],
 \       'description': 'Fix ruby files with rubocop --auto-correct.',
 \   },
+\   'standard': {
+\       'function': 'ale#fixers#standard#Fix',
+\       'suggested_filetypes': ['javascript'],
+\       'description': 'Fix JavaScript files using standard --fix',
+\   },
 \}
 
 " Reset the function registry to the default entries.

autoload/ale/fixers/standard.vim

@@ -0,0 +1,27 @@
+" Author: Sumner Evans <sumner.evans98@gmail.com>
+" Description: Fixing files with Standard.
+
+function! ale#fixers#standard#GetExecutable(buffer) abort
+    return ale#node#FindExecutable(a:buffer, 'javascript_standard', [
+    \   'node_modules/standard/bin/cmd.js',
+    \   'node_modules/.bin/standard',
+    \])
+endfunction
+
+function! ale#fixers#standard#Fix(buffer) abort
+    let l:executable = ale#fixers#standard#GetExecutable(a:buffer)
+
+    if ale#Has('win32') && l:executable =~? 'cmd\.js$'
+        " For Windows, if we detect an standard.js script, we need to execute
+        " it with node, or the file can be opened with a text editor.
+        let l:head = 'node ' . ale#Escape(l:executable)
+    else
+        let l:head = ale#Escape(l:executable)
+    endif
+
+    return {
+    \   'command': l:head
+    \       . ' --fix %t',
+    \   'read_temporary_file': 1,
+    \}
+endfunction

test/fixers/test_standard_fixer_callback.vader

@@ -0,0 +1,32 @@
+Before:
+  call ale#test#SetDirectory('/testplugin/test/fixers')
+
+After:
+  let g:ale_has_override = {}
+  call ale#test#RestoreDirectory()
+
+Execute(The path to standard.js should be run on Unix):
+  call ale#test#SetFilename('../eslint-test-files/react-app/subdir/testfile.js')
+
+  AssertEqual
+  \ {
+  \   'read_temporary_file': 1,
+  \   'command':
+  \     ale#Escape(simplify(g:dir . '/../eslint-test-files/react-app/node_modules/standard/bin/cmd.js'))
+  \     . ' --fix %t',
+  \ },
+  \ ale#fixers#standard#Fix(bufnr(''))
+
+Execute(The standard fixer with standard.js should be run with node on Windows):
+  call ale#test#SetFilename('../eslint-test-files/react-app/subdir/testfile.js')
+  let g:ale_has_override['win32'] = 1
+
+  " We have to execute the file with node.
+  AssertEqual
+  \ {
+  \   'read_temporary_file': 1,
+  \   'command': 'node '
+  \     . ale#Escape(simplify(g:dir . '/../eslint-test-files/react-app/node_modules/standard/bin/cmd.js'))
+  \     . ' --fix %t',
+  \ },
+  \ ale#fixers#standard#Fix(bufnr(''))