f49f615ef6
This PR first and formost implements support for dot-seperate filetypes, a very trivial change. This closes #132 But more importantly, this PR vastly improves the test quality for `ale#linter#Get`. It enables us to reset the state of ale's internal linter cache, to facilitate better testing, as well as making use of mocked linters instead of depending on linters on disk (which may change). In addition, a dummy linter is defined to test the autoloading behavior. Header guards were removed from all linters as: * A: ale won't try and load linters if they already exist in memory * B: we can't reset state for testing if they can't be loaded again
34 lines
1.1 KiB
VimL
34 lines
1.1 KiB
VimL
" Author: Chris Kyrouac - https://github.com/fijshion
|
|
" Description: JSHint for Javascript files
|
|
|
|
let g:ale_javascript_jshint_executable =
|
|
\ get(g:, 'ale_javascript_jshint_executable', 'jshint')
|
|
|
|
function! ale_linters#javascript#jshint#GetCommand(buffer)
|
|
" Set this to the location of the jshint configuration file to
|
|
" use a fixed location for .jshintrc
|
|
if exists('g:ale_jshint_config_loc')
|
|
let l:jshint_config = g:ale_jshint_config_loc
|
|
else
|
|
" Look for the JSHint config in parent directories.
|
|
let l:jshint_config = ale#util#FindNearestFile(a:buffer, '.jshintrc')
|
|
endif
|
|
|
|
let l:command = g:ale_javascript_jshint_executable . ' --reporter unix'
|
|
|
|
if !empty(l:jshint_config)
|
|
let l:command .= ' --config ' . fnameescape(l:jshint_config)
|
|
endif
|
|
|
|
let l:command .= ' -'
|
|
|
|
return l:command
|
|
endfunction
|
|
|
|
call ale#linter#Define('javascript', {
|
|
\ 'name': 'jshint',
|
|
\ 'executable': g:ale_javascript_jshint_executable,
|
|
\ 'command_callback': 'ale_linters#javascript#jshint#GetCommand',
|
|
\ 'callback': 'ale#handlers#HandleUnixFormatAsError',
|
|
\})
|