f49f615ef6
This PR first and formost implements support for dot-seperate filetypes, a very trivial change. This closes #132 But more importantly, this PR vastly improves the test quality for `ale#linter#Get`. It enables us to reset the state of ale's internal linter cache, to facilitate better testing, as well as making use of mocked linters instead of depending on linters on disk (which may change). In addition, a dummy linter is defined to test the autoloading behavior. Header guards were removed from all linters as: * A: ale won't try and load linters if they already exist in memory * B: we can't reset state for testing if they can't be loaded again
46 lines
1.4 KiB
VimL
46 lines
1.4 KiB
VimL
" Author: Masahiro H https://github.com/mshr-h
|
|
" Description: iverilog for verilog files
|
|
|
|
function! ale_linters#verilog#iverilog#Handle(buffer, lines)
|
|
" Look for lines like the following.
|
|
"
|
|
" tb_me_top.v:37: warning: Instantiating module me_top with dangling input port 1 (rst_n) floating.
|
|
" tb_me_top.v:17: syntax error
|
|
" memory_single_port.v:2: syntax error
|
|
" tb_me_top.v:17: error: Invalid module instantiation
|
|
let l:pattern = '^[^:]\+:\(\d\+\): \(warning\|error\|syntax error\)\(: \(.\+\)\)\?'
|
|
let l:output = []
|
|
|
|
for l:line in a:lines
|
|
let l:match = matchlist(l:line, l:pattern)
|
|
|
|
if len(l:match) == 0
|
|
continue
|
|
endif
|
|
|
|
let l:line = l:match[1] + 0
|
|
let l:type = l:match[2] =~# 'error' ? 'E' : 'W'
|
|
let l:text = l:match[2] ==# 'syntax error' ? 'syntax error' : l:match[4]
|
|
|
|
call add(l:output, {
|
|
\ 'bufnr': a:buffer,
|
|
\ 'lnum': l:line,
|
|
\ 'vcol': 0,
|
|
\ 'col': 1,
|
|
\ 'text': l:text,
|
|
\ 'type': l:type,
|
|
\ 'nr': -1,
|
|
\})
|
|
endfor
|
|
|
|
return l:output
|
|
endfunction
|
|
|
|
call ale#linter#Define('verilog', {
|
|
\ 'name': 'iverilog',
|
|
\ 'output_stream': 'stderr',
|
|
\ 'executable': 'iverilog',
|
|
\ 'command': g:ale#util#stdin_wrapper . ' .v iverilog -t null -Wall',
|
|
\ 'callback': 'ale_linters#verilog#iverilog#Handle',
|
|
\})
|