f49f615ef6
This PR first and formost implements support for dot-seperate filetypes, a very trivial change. This closes #132 But more importantly, this PR vastly improves the test quality for `ale#linter#Get`. It enables us to reset the state of ale's internal linter cache, to facilitate better testing, as well as making use of mocked linters instead of depending on linters on disk (which may change). In addition, a dummy linter is defined to test the autoloading behavior. Header guards were removed from all linters as: * A: ale won't try and load linters if they already exist in memory * B: we can't reset state for testing if they can't be loaded again
53 lines
1.5 KiB
VimL
53 lines
1.5 KiB
VimL
" Author: jwilliams108 <https://github.com/jwilliams108>
|
|
" Description: phpcs for PHP files
|
|
|
|
function! ale_linters#php#phpcs#GetCommand(buffer)
|
|
let l:command = 'phpcs -s --report=emacs --stdin-path=%s'
|
|
|
|
" This option can be set to change the standard used by phpcs
|
|
if exists('g:ale_php_phpcs_standard')
|
|
let l:command .= ' --standard=' . g:ale_php_phpcs_standard
|
|
endif
|
|
|
|
return l:command
|
|
endfunction
|
|
|
|
function! ale_linters#php#phpcs#Handle(buffer, lines)
|
|
" Matches against lines like the following:
|
|
"
|
|
" /path/to/some-filename.php:18:3: error - Line indented incorrectly; expected 4 spaces, found 2 (Generic.WhiteSpace.ScopeIndent.IncorrectExact)
|
|
let l:pattern = '^.*:\(\d\+\):\(\d\+\): \(.\+\) - \(.\+\) \(\(.\+\)\)$'
|
|
let l:output = []
|
|
|
|
for l:line in a:lines
|
|
let l:match = matchlist(l:line, l:pattern)
|
|
|
|
if len(l:match) == 0
|
|
continue
|
|
endif
|
|
|
|
let l:text = l:match[4]
|
|
let l:type = l:match[3]
|
|
|
|
" vcol is Needed to indicate that the column is a character.
|
|
call add(l:output, {
|
|
\ 'bufnr': a:buffer,
|
|
\ 'lnum': l:match[1] + 0,
|
|
\ 'vcol': 0,
|
|
\ 'col': l:match[2] + 0,
|
|
\ 'text': l:text,
|
|
\ 'type': l:type ==# 'error' ? 'E' : 'W',
|
|
\ 'nr': -1,
|
|
\})
|
|
endfor
|
|
|
|
return l:output
|
|
endfunction
|
|
|
|
call ale#linter#Define('php', {
|
|
\ 'name': 'phpcs',
|
|
\ 'executable': 'phpcs',
|
|
\ 'command_callback': 'ale_linters#php#phpcs#GetCommand',
|
|
\ 'callback': 'ale_linters#php#phpcs#Handle',
|
|
\})
|