f49f615ef6
This PR first and formost implements support for dot-seperate filetypes, a very trivial change. This closes #132 But more importantly, this PR vastly improves the test quality for `ale#linter#Get`. It enables us to reset the state of ale's internal linter cache, to facilitate better testing, as well as making use of mocked linters instead of depending on linters on disk (which may change). In addition, a dummy linter is defined to test the autoloading behavior. Header guards were removed from all linters as: * A: ale won't try and load linters if they already exist in memory * B: we can't reset state for testing if they can't be loaded again
43 lines
1.3 KiB
VimL
43 lines
1.3 KiB
VimL
" Author: Sol Bekic https://github.com/s-ol
|
|
" Description: luacheck linter for lua files
|
|
|
|
let g:ale_lua_luacheck_executable =
|
|
\ get(g:, 'ale_lua_luacheck_executable', 'luacheck')
|
|
|
|
function! ale_linters#lua#luacheck#Handle(buffer, lines)
|
|
" Matches patterns line the following:
|
|
"
|
|
" artal.lua:159:17: (W111) shadowing definition of loop variable 'i' on line 106
|
|
" artal.lua:182:7: (W213) unused loop variable 'i'
|
|
let l:pattern = '^.*:\(\d\+\):\(\d\+\): (\([WE]\)\d\+) \(.\+\)$'
|
|
let l:output = []
|
|
|
|
for l:line in a:lines
|
|
let l:match = matchlist(l:line, l:pattern)
|
|
|
|
if len(l:match) == 0
|
|
continue
|
|
endif
|
|
|
|
" vcol is Needed to indicate that the column is a character.
|
|
call add(l:output, {
|
|
\ 'bufnr': a:buffer,
|
|
\ 'lnum': l:match[1] + 0,
|
|
\ 'vcol': 0,
|
|
\ 'col': l:match[2] + 0,
|
|
\ 'text': l:match[4],
|
|
\ 'type': l:match[3],
|
|
\ 'nr': -1,
|
|
\})
|
|
endfor
|
|
|
|
return l:output
|
|
endfunction
|
|
|
|
call ale#linter#Define('lua', {
|
|
\ 'name': 'luacheck',
|
|
\ 'executable': g:ale_lua_luacheck_executable,
|
|
\ 'command': g:ale_lua_luacheck_executable . ' --formatter plain --codes --filename %s -',
|
|
\ 'callback': 'ale_linters#lua#luacheck#Handle',
|
|
\})
|