4b0f3257dd
* Remove 'col' from linters where it is hardcoded to 1 When 'col' is 1, the first column will get highlighted for no reason. It should be 0 (which is the default). In the scalac linter there was also a check about the outcome of `stridx`. It would set l:col to 0 if it was -1, and then it uses `'col': l:col + 1` to convert the outcome of `stridx` to the actual column number. This will make 'col' equals 1 when there is no match. We can remove the check because `-1 + 1 = 0`. * Remove outdated comments about vcol vcol was added as a default, and the loclists that follow these comments do not contain 'vcol' anymore
52 lines
1.4 KiB
VimL
52 lines
1.4 KiB
VimL
" Author: ynonp - https://github.com/ynonp
|
|
" Description: rubocop for Ruby files
|
|
|
|
function! ale_linters#ruby#rubocop#Handle(buffer, lines) abort
|
|
" Matches patterns line the following:
|
|
"
|
|
" <path>:83:29: C: Prefer single-quoted strings when you don't
|
|
" need string interpolation or special symbols.
|
|
let l:pattern = '\v:(\d+):(\d+): (.): (.+)'
|
|
let l:output = []
|
|
|
|
for l:line in a:lines
|
|
let l:match = matchlist(l:line, l:pattern)
|
|
|
|
if len(l:match) == 0
|
|
continue
|
|
endif
|
|
|
|
let l:text = l:match[4]
|
|
let l:type = l:match[3]
|
|
|
|
call add(l:output, {
|
|
\ 'bufnr': a:buffer,
|
|
\ 'lnum': l:match[1] + 0,
|
|
\ 'col': l:match[2] + 0,
|
|
\ 'text': l:text,
|
|
\ 'type': index(['F', 'E'], l:type) != -1 ? 'E' : 'W',
|
|
\})
|
|
endfor
|
|
|
|
return l:output
|
|
endfunction
|
|
|
|
function! ale_linters#ruby#rubocop#GetCommand(buffer) abort
|
|
return 'rubocop --format emacs --force-exclusion ' .
|
|
\ g:ale_ruby_rubocop_options .
|
|
\ ' --stdin ' . bufname(a:buffer)
|
|
endfunction
|
|
|
|
" Set this option to change Rubocop options.
|
|
if !exists('g:ale_ruby_rubocop_options')
|
|
" let g:ale_ruby_rubocop_options = '--lint'
|
|
let g:ale_ruby_rubocop_options = ''
|
|
endif
|
|
|
|
call ale#linter#Define('ruby', {
|
|
\ 'name': 'rubocop',
|
|
\ 'executable': 'rubocop',
|
|
\ 'command_callback': 'ale_linters#ruby#rubocop#GetCommand',
|
|
\ 'callback': 'ale_linters#ruby#rubocop#Handle',
|
|
\})
|