7f0ce89d2b
* First pass at optimizing ale to autoload First off, the structure/function names should be revised a bit, but I will wait for @w0rp's input before unifying the naming style. Second off, the docs probably need some more work, I just did some simple find-and-replace work. With that said, this pull brings major performance gains for ale. On my slowest system, fully loading ale and all its code takes around 150ms. I have moved all of ale's autoload-able code to autoload/, and in addition, implemented lazy-loading of linters. This brings load time on that same system down to 5ms. The only downside of lazy loading is that `g:ale_linters` cannot be changed at runtime; however, it also speeds up performance at runtime by simplfying the logic greatly. Please let me know what you think! Closes #59 * Address Travis/Vint errors For some reason, ale isn't running vint for me... * Incorporate feedback, make fixes Lazy-loading logic is much improved. * Add header comments; remove incorrect workaround * Remove unneeded plugin guards * Fix lazy-loading linter logic Set the wrong variable.... * Fix capitialization
76 lines
2.1 KiB
VimL
76 lines
2.1 KiB
VimL
" Author: w0rp <devw0rp@gmail.com>
|
|
" Description: ghc for Haskell files
|
|
|
|
if exists('g:loaded_ale_linters_haskell_ghc')
|
|
finish
|
|
endif
|
|
|
|
let g:loaded_ale_linters_haskell_ghc = 1
|
|
|
|
function! ale_linters#haskell#ghc#Handle(buffer, lines)
|
|
" Look for lines like the following.
|
|
"
|
|
" /dev/stdin:28:26: Not in scope: `>>>>>'
|
|
let pattern = '^[^:]\+:\(\d\+\):\(\d\+\): \(.\+\)$'
|
|
let output = []
|
|
|
|
" For some reason the output coming out of the GHC through the wrapper
|
|
" script breaks the lines up in strange ways. So we have to join some
|
|
" lines back together again.
|
|
let corrected_lines = []
|
|
|
|
for line in a:lines
|
|
if len(matchlist(line, pattern)) > 0
|
|
call add(corrected_lines, line)
|
|
if line !~# ': error:$'
|
|
call add(corrected_lines, '')
|
|
endif
|
|
elseif line ==# ''
|
|
call add(corrected_lines, line)
|
|
else
|
|
if len(corrected_lines) > 0
|
|
if corrected_lines[-1] =~# ': error:$'
|
|
let line = substitute(line, '\v^\s+', ' ', '')
|
|
endif
|
|
let corrected_lines[-1] .= line
|
|
endif
|
|
endif
|
|
endfor
|
|
|
|
for line in corrected_lines
|
|
let l:match = matchlist(line, pattern)
|
|
|
|
if len(l:match) == 0
|
|
continue
|
|
endif
|
|
|
|
call add(output, {
|
|
\ 'bufnr': a:buffer,
|
|
\ 'lnum': l:match[1] + 0,
|
|
\ 'vcol': 0,
|
|
\ 'col': l:match[2] + 0,
|
|
\ 'text': l:match[3],
|
|
\ 'type': 'E',
|
|
\ 'nr': -1,
|
|
\})
|
|
endfor
|
|
|
|
return output
|
|
endfunction
|
|
|
|
call ale#linter#Define('haskell', {
|
|
\ 'name': 'ghc',
|
|
\ 'output_stream': 'stderr',
|
|
\ 'executable': 'ghc',
|
|
\ 'command': g:ale#util#stdin_wrapper . ' .hs ghc -fno-code -v0',
|
|
\ 'callback': 'ale_linters#haskell#ghc#Handle',
|
|
\})
|
|
|
|
call ale#linter#Define('haskell', {
|
|
\ 'name': 'stack-ghc',
|
|
\ 'output_stream': 'stderr',
|
|
\ 'executable': 'stack',
|
|
\ 'command': g:ale#util#stdin_wrapper . ' .hs stack ghc -- -fno-code -v0',
|
|
\ 'callback': 'ale_linters#haskell#ghc#Handle',
|
|
\})
|