119 lines
4.5 KiB
VimL
119 lines
4.5 KiB
VimL
scriptencoding utf-8
|
||
" Author: w0rp <devw0rp@gmail.com>
|
||
" Description: This file defines some standard error format handlers. Any
|
||
" linter which outputs warnings and errors in a format accepted by one of
|
||
" these functions can simply use one of these pre-defined error handlers.
|
||
|
||
let s:path_pattern = '[a-zA-Z]\?\\\?:\?[[:alnum:]/\.-]\+'
|
||
|
||
function! s:HandleUnixFormat(buffer, lines, type) abort
|
||
" Matches patterns line the following:
|
||
"
|
||
" file.go:27: missing argument for Printf("%s"): format reads arg 2, have only 1 args
|
||
" file.go:53:10: if block ends with a return statement, so drop this else and outdent its block (move short variable declaration to its own line if necessary)
|
||
" file.go:5:2: expected declaration, found 'STRING' "log"
|
||
let l:pattern = '^' . s:path_pattern . ':\(\d\+\):\?\(\d\+\)\?: \(.\+\)$'
|
||
let l:output = []
|
||
|
||
for l:line in a:lines
|
||
let l:match = matchlist(l:line, l:pattern)
|
||
|
||
if len(l:match) == 0
|
||
continue
|
||
endif
|
||
|
||
" vcol is Needed to indicate that the column is a character.
|
||
call add(l:output, {
|
||
\ 'bufnr': a:buffer,
|
||
\ 'lnum': l:match[1] + 0,
|
||
\ 'vcol': 0,
|
||
\ 'col': l:match[2] + 0,
|
||
\ 'text': l:match[3],
|
||
\ 'type': a:type,
|
||
\ 'nr': -1,
|
||
\})
|
||
endfor
|
||
|
||
return l:output
|
||
endfunction
|
||
|
||
function! ale#handlers#HandleUnixFormatAsError(buffer, lines) abort
|
||
return s:HandleUnixFormat(a:buffer, a:lines, 'E')
|
||
endfunction
|
||
|
||
function! ale#handlers#HandleUnixFormatAsWarning(buffer, lines) abort
|
||
return s:HandleUnixFormat(a:buffer, a:lines, 'W')
|
||
endfunction
|
||
|
||
|
||
function! ale#handlers#HandleGCCFormat(buffer, lines) abort
|
||
" Look for lines like the following.
|
||
"
|
||
" <stdin>:8:5: warning: conversion lacks type at end of format [-Wformat=]
|
||
" <stdin>:10:27: error: invalid operands to binary - (have ‘int’ and ‘char *’)
|
||
" -:189:7: note: $/${} is unnecessary on arithmetic variables. [SC2004]
|
||
let l:pattern = '^.\+:\(\d\+\):\(\d\+\): \([^:]\+\): \(.\+\)$'
|
||
let l:output = []
|
||
|
||
for l:line in a:lines
|
||
let l:match = matchlist(l:line, l:pattern)
|
||
|
||
if len(l:match) == 0
|
||
continue
|
||
endif
|
||
|
||
call add(l:output, {
|
||
\ 'bufnr': a:buffer,
|
||
\ 'lnum': l:match[1] + 0,
|
||
\ 'vcol': 0,
|
||
\ 'col': l:match[2] + 0,
|
||
\ 'text': l:match[4],
|
||
\ 'type': l:match[3] ==# 'error' ? 'E' : 'W',
|
||
\ 'nr': -1,
|
||
\})
|
||
endfor
|
||
|
||
return l:output
|
||
endfunction
|
||
|
||
function! ale#handlers#HandleCSSLintFormat(buffer, lines) abort
|
||
" Matches patterns line the following:
|
||
"
|
||
" something.css: line 2, col 1, Error - Expected RBRACE at line 2, col 1. (errors)
|
||
" something.css: line 2, col 5, Warning - Expected (inline | block | list-item | inline-block | table | inline-table | table-row-group | table-header-group | table-footer-group | table-row | table-column-group | table-column | table-cell | table-caption | grid | inline-grid | run-in | ruby | ruby-base | ruby-text | ruby-base-container | ruby-text-container | contents | none | -moz-box | -moz-inline-block | -moz-inline-box | -moz-inline-grid | -moz-inline-stack | -moz-inline-table | -moz-grid | -moz-grid-group | -moz-grid-line | -moz-groupbox | -moz-deck | -moz-popup | -moz-stack | -moz-marker | -webkit-box | -webkit-inline-box | -ms-flexbox | -ms-inline-flexbox | flex | -webkit-flex | inline-flex | -webkit-inline-flex) but found 'wat'. (known-properties)
|
||
"
|
||
" These errors can be very massive, so the type will be moved to the front
|
||
" so you can actually read the error type.
|
||
let l:pattern = '^.*: line \(\d\+\), col \(\d\+\), \(Error\|Warning\) - \(.\+\) (\([^)]\+\))$'
|
||
let l:output = []
|
||
|
||
for l:line in a:lines
|
||
let l:match = matchlist(l:line, l:pattern)
|
||
|
||
if len(l:match) == 0
|
||
continue
|
||
endif
|
||
|
||
let l:text = l:match[4]
|
||
let l:type = l:match[3]
|
||
let l:errorGroup = l:match[5]
|
||
|
||
" Put the error group at the front, so we can see what kind of error
|
||
" it is on small echo lines.
|
||
let l:text = '(' . l:errorGroup . ') ' . l:text
|
||
|
||
" vcol is Needed to indicate that the column is a character.
|
||
call add(l:output, {
|
||
\ 'bufnr': a:buffer,
|
||
\ 'lnum': l:match[1] + 0,
|
||
\ 'vcol': 0,
|
||
\ 'col': l:match[2] + 0,
|
||
\ 'text': l:text,
|
||
\ 'type': l:type ==# 'Warning' ? 'W' : 'E',
|
||
\ 'nr': -1,
|
||
\})
|
||
endfor
|
||
|
||
return l:output
|
||
endfunction
|