4b0f3257dd
* Remove 'col' from linters where it is hardcoded to 1 When 'col' is 1, the first column will get highlighted for no reason. It should be 0 (which is the default). In the scalac linter there was also a check about the outcome of `stridx`. It would set l:col to 0 if it was -1, and then it uses `'col': l:col + 1` to convert the outcome of `stridx` to the actual column number. This will make 'col' equals 1 when there is no match. We can remove the check because `-1 + 1 = 0`. * Remove outdated comments about vcol vcol was added as a default, and the loclists that follow these comments do not contain 'vcol' anymore
62 lines
1.7 KiB
VimL
62 lines
1.7 KiB
VimL
" Author: awlayton <alex@layton.in>
|
|
" Description: mlint for MATLAB files
|
|
|
|
let g:ale_matlab_mlint_executable =
|
|
\ get(g:, 'ale_matlab_mlint_executable', 'mlint')
|
|
|
|
function! ale_linters#matlab#mlint#GetExecutable(buffer) abort
|
|
return g:ale_matlab_mlint_executable
|
|
endfunction
|
|
|
|
function! ale_linters#matlab#mlint#GetCommand(buffer) abort
|
|
let l:executable = ale_linters#matlab#mlint#GetExecutable(a:buffer)
|
|
|
|
return l:executable . ' -id %t'
|
|
endfunction
|
|
|
|
function! ale_linters#matlab#mlint#Handle(buffer, lines) abort
|
|
" Matches patterns like the following:
|
|
"
|
|
" L 27 (C 1): FNDEF: Terminate statement with semicolon to suppress output.
|
|
" L 30 (C 13-15): FNDEF: A quoted string is unterminated.
|
|
let l:pattern = '^L \(\d\+\) (C \([0-9-]\+\)): \([A-Z]\+\): \(.\+\)$'
|
|
let l:output = []
|
|
|
|
for l:line in a:lines
|
|
let l:match = matchlist(l:line, l:pattern)
|
|
|
|
if len(l:match) == 0
|
|
continue
|
|
endif
|
|
|
|
let l:lnum = l:match[1] + 0
|
|
let l:col = l:match[2] + 0
|
|
let l:code = l:match[3]
|
|
let l:text = l:match[4]
|
|
|
|
" Suppress erroneous waring about filename
|
|
" TODO: Enable this error when copying filename is supported
|
|
if l:code ==# 'FNDEF'
|
|
continue
|
|
endif
|
|
|
|
call add(l:output, {
|
|
\ 'bufnr': a:buffer,
|
|
\ 'lnum': l:lnum,
|
|
\ 'col': l:col,
|
|
\ 'text': l:text,
|
|
\ 'type': 'W',
|
|
\})
|
|
endfor
|
|
|
|
return l:output
|
|
endfunction
|
|
|
|
call ale#linter#Define('matlab', {
|
|
\ 'name': 'mlint',
|
|
\ 'executable_callback': 'ale_linters#matlab#mlint#GetExecutable',
|
|
\ 'command_callback': 'ale_linters#matlab#mlint#GetCommand',
|
|
\ 'output_stream': 'stderr',
|
|
\ 'callback': 'ale_linters#matlab#mlint#Handle',
|
|
\})
|