7f0ce89d2b
* First pass at optimizing ale to autoload First off, the structure/function names should be revised a bit, but I will wait for @w0rp's input before unifying the naming style. Second off, the docs probably need some more work, I just did some simple find-and-replace work. With that said, this pull brings major performance gains for ale. On my slowest system, fully loading ale and all its code takes around 150ms. I have moved all of ale's autoload-able code to autoload/, and in addition, implemented lazy-loading of linters. This brings load time on that same system down to 5ms. The only downside of lazy loading is that `g:ale_linters` cannot be changed at runtime; however, it also speeds up performance at runtime by simplfying the logic greatly. Please let me know what you think! Closes #59 * Address Travis/Vint errors For some reason, ale isn't running vint for me... * Incorporate feedback, make fixes Lazy-loading logic is much improved. * Add header comments; remove incorrect workaround * Remove unneeded plugin guards * Fix lazy-loading linter logic Set the wrong variable.... * Fix capitialization
84 lines
2.3 KiB
VimL
84 lines
2.3 KiB
VimL
" Author: w0rp <devw0rp@gmail.com>
|
|
" Description: Lints sh files using bash -n
|
|
|
|
if exists('g:loaded_ale_linters_sh_shell')
|
|
finish
|
|
endif
|
|
|
|
let g:loaded_ale_linters_sh_shell = 1
|
|
|
|
" This option can be changed to change the default shell when the shell
|
|
" cannot be taken from the hashbang line.
|
|
if !exists('g:ale_linters_sh_shell_default_shell')
|
|
let g:ale_linters_sh_shell_default_shell = fnamemodify($SHELL, ':t')
|
|
|
|
if g:ale_linters_sh_shell_default_shell ==# ''
|
|
let g:ale_linters_sh_shell_default_shell = 'bash'
|
|
endif
|
|
endif
|
|
|
|
function! ale_linters#sh#shell#GetExecutable(buffer)
|
|
let banglines = getbufline(a:buffer, 1)
|
|
|
|
" Take the shell executable from the hashbang, if we can.
|
|
if len(banglines) == 1 && banglines[0] =~# '^#!'
|
|
" Remove options like -e, etc.
|
|
let line = substitute(banglines[0], '--\?[a-zA-Z0-9]\+', '', 'g')
|
|
|
|
for possible_shell in ['bash', 'tcsh', 'csh', 'zsh', 'sh']
|
|
if line =~# possible_shell . '\s*$'
|
|
return possible_shell
|
|
endif
|
|
endfor
|
|
endif
|
|
|
|
return g:ale_linters_sh_shell_default_shell
|
|
endfunction
|
|
|
|
function! ale_linters#sh#shell#GetCommand(buffer)
|
|
return ale_linters#sh#shell#GetExecutable(a:buffer) . ' -n'
|
|
endfunction
|
|
|
|
function! ale_linters#sh#shell#Handle(buffer, lines)
|
|
" Matches patterns line the following:
|
|
"
|
|
" bash: line 13: syntax error near unexpected token `d'
|
|
" sh: 11: Syntax error: "(" unexpected
|
|
let pattern = '^[^:]\+: \%(\w\+ \|\)\(\d\+\): \(.\+\)'
|
|
let output = []
|
|
|
|
for line in a:lines
|
|
let l:match = matchlist(line, pattern)
|
|
|
|
if len(l:match) == 0
|
|
continue
|
|
endif
|
|
|
|
let line = l:match[1] + 0
|
|
let column = 1
|
|
let text = l:match[2]
|
|
let type = 'E'
|
|
|
|
" vcol is Needed to indicate that the column is a character.
|
|
call add(output, {
|
|
\ 'bufnr': a:buffer,
|
|
\ 'lnum': line,
|
|
\ 'vcol': 0,
|
|
\ 'col': column,
|
|
\ 'text': text,
|
|
\ 'type': type,
|
|
\ 'nr': -1,
|
|
\})
|
|
endfor
|
|
|
|
return output
|
|
endfunction
|
|
|
|
call ale#linter#Define('sh', {
|
|
\ 'name': 'shell',
|
|
\ 'output_stream': 'stderr',
|
|
\ 'executable_callback': 'ale_linters#sh#shell#GetExecutable',
|
|
\ 'command_callback': 'ale_linters#sh#shell#GetCommand',
|
|
\ 'callback': 'ale_linters#sh#shell#Handle',
|
|
\})
|