4b0f3257dd
* Remove 'col' from linters where it is hardcoded to 1 When 'col' is 1, the first column will get highlighted for no reason. It should be 0 (which is the default). In the scalac linter there was also a check about the outcome of `stridx`. It would set l:col to 0 if it was -1, and then it uses `'col': l:col + 1` to convert the outcome of `stridx` to the actual column number. This will make 'col' equals 1 when there is no match. We can remove the check because `-1 + 1 = 0`. * Remove outdated comments about vcol vcol was added as a default, and the loclists that follow these comments do not contain 'vcol' anymore
55 lines
1.6 KiB
VimL
55 lines
1.6 KiB
VimL
" Author: Prashanth Chandra https://github.com/prashcr
|
|
" Description: coffeelint linter for coffeescript files
|
|
|
|
function! ale_linters#coffee#coffeelint#GetExecutable(buffer) abort
|
|
return ale#util#ResolveLocalPath(
|
|
\ a:buffer,
|
|
\ 'node_modules/.bin/coffeelint',
|
|
\ 'coffeelint'
|
|
\)
|
|
endfunction
|
|
|
|
function! ale_linters#coffee#coffeelint#GetCommand(buffer) abort
|
|
return ale_linters#coffee#coffeelint#GetExecutable(a:buffer)
|
|
\ . ' --stdin --reporter csv'
|
|
endfunction
|
|
|
|
function! ale_linters#coffee#coffeelint#Handle(buffer, lines) abort
|
|
" Matches patterns like the following:
|
|
"
|
|
" path,lineNumber,lineNumberEnd,level,message
|
|
" stdin,14,,error,Throwing strings is forbidden
|
|
"
|
|
" Note that we currently ignore lineNumberEnd for multiline errors
|
|
let l:pattern = 'stdin,\(\d\+\),\(\d*\),\(.\{-1,}\),\(.\+\)'
|
|
let l:output = []
|
|
|
|
for l:line in a:lines
|
|
let l:match = matchlist(l:line, l:pattern)
|
|
|
|
if len(l:match) == 0
|
|
continue
|
|
endif
|
|
|
|
let l:line = l:match[1] + 0
|
|
let l:type = l:match[3] ==# 'error' ? 'E' : 'W'
|
|
let l:text = l:match[4]
|
|
|
|
call add(l:output, {
|
|
\ 'bufnr': a:buffer,
|
|
\ 'lnum': l:line,
|
|
\ 'text': l:text,
|
|
\ 'type': l:type,
|
|
\})
|
|
endfor
|
|
|
|
return l:output
|
|
endfunction
|
|
|
|
call ale#linter#Define('coffee', {
|
|
\ 'name': 'coffeelint',
|
|
\ 'executable_callback': 'ale_linters#coffee#coffeelint#GetExecutable',
|
|
\ 'command_callback': 'ale_linters#coffee#coffeelint#GetCommand',
|
|
\ 'callback': 'ale_linters#coffee#coffeelint#Handle',
|
|
\})
|