4b0f3257dd
* Remove 'col' from linters where it is hardcoded to 1 When 'col' is 1, the first column will get highlighted for no reason. It should be 0 (which is the default). In the scalac linter there was also a check about the outcome of `stridx`. It would set l:col to 0 if it was -1, and then it uses `'col': l:col + 1` to convert the outcome of `stridx` to the actual column number. This will make 'col' equals 1 when there is no match. We can remove the check because `-1 + 1 = 0`. * Remove outdated comments about vcol vcol was added as a default, and the loclists that follow these comments do not contain 'vcol' anymore
43 lines
1.1 KiB
VimL
43 lines
1.1 KiB
VimL
" Author: Prashanth Chandra https://github.com/prashcr, Aleh Kashnikau https://github.com/mkusher
|
|
" Description: type checker for TypeScript files
|
|
|
|
function! ale_linters#typescript#typecheck#Handle(buffer, lines) abort
|
|
" Matches patterns like the following:
|
|
"
|
|
" hello.ts[7, 41]: Property 'a' does not exist on type 'A'
|
|
" hello.ts[16, 7]: Type 'A' is not assignable to type 'B'
|
|
"
|
|
let l:pattern = '.\+\.ts\[\(\d\+\), \(\d\+\)\]: \(.\+\)'
|
|
let l:output = []
|
|
|
|
for l:line in a:lines
|
|
let l:match = matchlist(l:line, l:pattern)
|
|
|
|
if len(l:match) == 0
|
|
continue
|
|
endif
|
|
|
|
let l:line = l:match[1] + 0
|
|
let l:column = l:match[2] + 0
|
|
let l:type = 'E'
|
|
let l:text = l:match[3]
|
|
|
|
call add(l:output, {
|
|
\ 'bufnr': a:buffer,
|
|
\ 'lnum': l:line,
|
|
\ 'col': l:column,
|
|
\ 'text': l:text,
|
|
\ 'type': l:type,
|
|
\})
|
|
endfor
|
|
|
|
return l:output
|
|
endfunction
|
|
|
|
call ale#linter#Define('typescript', {
|
|
\ 'name': 'typecheck',
|
|
\ 'executable': 'typecheck',
|
|
\ 'command': 'typecheck %s',
|
|
\ 'callback': 'ale_linters#typescript#typecheck#Handle',
|
|
\})
|