f49f615ef6
This PR first and formost implements support for dot-seperate filetypes, a very trivial change. This closes #132 But more importantly, this PR vastly improves the test quality for `ale#linter#Get`. It enables us to reset the state of ale's internal linter cache, to facilitate better testing, as well as making use of mocked linters instead of depending on linters on disk (which may change). In addition, a dummy linter is defined to test the autoloading behavior. Header guards were removed from all linters as: * A: ale won't try and load linters if they already exist in memory * B: we can't reset state for testing if they can't be loaded again
40 lines
1.0 KiB
VimL
40 lines
1.0 KiB
VimL
" Author: Spencer Wood <https://github.com/scwood>
|
|
" Description: This file adds support for checking PHP with php-cli
|
|
|
|
function! ale_linters#php#php#Handle(buffer, lines)
|
|
" Matches patterns like the following:
|
|
"
|
|
" Parse error: parse error in - on line 7
|
|
let l:pattern = 'Parse error:\s\+\(.\+\) on line \(\d\+\)'
|
|
let l:output = []
|
|
|
|
for l:line in a:lines
|
|
let l:match = matchlist(l:line, l:pattern)
|
|
|
|
if len(l:match) == 0
|
|
continue
|
|
endif
|
|
|
|
" vcol is needed to indicate that the column is a character.
|
|
call add(l:output, {
|
|
\ 'bufnr': a:buffer,
|
|
\ 'lnum': l:match[2] + 0,
|
|
\ 'vcol': 0,
|
|
\ 'col': 1,
|
|
\ 'text': l:match[1],
|
|
\ 'type': 'E',
|
|
\ 'nr': -1,
|
|
\})
|
|
endfor
|
|
|
|
return l:output
|
|
endfunction
|
|
|
|
call ale#linter#Define('php', {
|
|
\ 'name': 'php',
|
|
\ 'executable': 'php',
|
|
\ 'output_stream': 'both',
|
|
\ 'command': 'php -l --',
|
|
\ 'callback': 'ale_linters#php#php#Handle',
|
|
\})
|