diff --git a/ale_linters/javascript/standard.vim b/ale_linters/javascript/standard.vim
index 15e6d78..fc534eb 100644
--- a/ale_linters/javascript/standard.vim
+++ b/ale_linters/javascript/standard.vim
@@ -7,13 +7,25 @@ call ale#Set('javascript_standard_options', '')
 
 function! ale_linters#javascript#standard#GetExecutable(buffer) abort
     return ale#node#FindExecutable(a:buffer, 'javascript_standard', [
+    \   'node_modules/standard/bin/cmd.js',
     \   'node_modules/.bin/standard',
     \])
 endfunction
 
 function! ale_linters#javascript#standard#GetCommand(buffer) abort
-    return ale#Escape(ale_linters#javascript#standard#GetExecutable(a:buffer))
-    \   . ' ' . ale#Var(a:buffer, 'javascript_standard_options')
+    let l:executable = ale_linters#javascript#standard#GetExecutable(a:buffer)
+
+    if ale#Has('win32') && l:executable =~? '\.js$'
+        " .js files have to be executed with Node on Windows.
+        let l:head = 'node ' . ale#Escape(l:executable)
+    else
+        let l:head = ale#Escape(l:executable)
+    endif
+
+    let l:options = ale#Var(a:buffer, 'javascript_standard_options')
+
+    return l:head
+    \   . (!empty(l:options) ? ' ' . l:options : '')
     \   . ' --stdin %s'
 endfunction
 
diff --git a/test/command_callback/standard-test-files/with-bin/node_modules/.bin/standard b/test/command_callback/standard-test-files/with-bin/node_modules/.bin/standard
new file mode 100755
index 0000000..e69de29
diff --git a/test/command_callback/standard-test-files/with-cmd/node_modules/standard/bin/cmd.js b/test/command_callback/standard-test-files/with-cmd/node_modules/standard/bin/cmd.js
new file mode 100755
index 0000000..e69de29
diff --git a/test/command_callback/test_standard_command_callback.vader b/test/command_callback/test_standard_command_callback.vader
new file mode 100644
index 0000000..fa90175
--- /dev/null
+++ b/test/command_callback/test_standard_command_callback.vader
@@ -0,0 +1,98 @@
+Before:
+  Save g:ale_javascript_standard_executable
+  Save g:ale_javascript_standard_use_global
+  Save g:ale_javascript_standard_options
+
+  unlet! b:executable
+  unlet! g:ale_javascript_standard_executable
+  unlet! b:ale_javascript_standard_executable
+  unlet! g:ale_javascript_standard_use_global
+  unlet! g:ale_javascript_standard_options
+
+  call ale#test#SetDirectory('/testplugin/test/command_callback')
+  call ale#test#SetFilename('testfile.js')
+
+  runtime ale_linters/javascript/standard.vim
+
+After:
+  Restore
+
+  unlet! b:executable
+
+  let g:ale_has_override = {}
+
+  call ale#test#SetFilename('test.txt')
+
+  call ale#test#RestoreDirectory()
+  call ale#linter#Reset()
+
+Execute(bin/cmd.js paths should be preferred):
+  call ale#test#SetFilename('standard-test-files/with-cmd/testfile.js')
+
+  let b:executable = g:dir
+  \ . '/standard-test-files/with-cmd/node_modules/standard/bin/cmd.js'
+
+  AssertEqual
+  \ b:executable,
+  \ ale_linters#javascript#standard#GetExecutable(bufnr(''))
+
+  AssertEqual
+  \ ale#Escape(b:executable) . ' --stdin %s',
+  \ ale_linters#javascript#standard#GetCommand(bufnr(''))
+
+Execute(.bin directories should be used too):
+  call ale#test#SetFilename('standard-test-files/with-bin/testfile.js')
+
+  let b:executable = g:dir
+  \ . '/standard-test-files/with-bin/node_modules/.bin/standard'
+
+  AssertEqual
+  \ b:executable,
+  \ ale_linters#javascript#standard#GetExecutable(bufnr(''))
+
+  AssertEqual
+  \ ale#Escape(b:executable) . ' --stdin %s',
+  \ ale_linters#javascript#standard#GetCommand(bufnr(''))
+
+Execute(.js files should be executed with node on Windows):
+  let g:ale_has_override['win32'] = 1
+
+  call ale#test#SetFilename('standard-test-files/with-cmd/testfile.js')
+
+  let b:executable = g:dir
+  \ . '/standard-test-files/with-cmd/node_modules/standard/bin/cmd.js'
+
+  AssertEqual
+  \ b:executable,
+  \ ale_linters#javascript#standard#GetExecutable(bufnr(''))
+
+  AssertEqual
+  \ 'node ' . ale#Escape(b:executable) . ' --stdin %s',
+  \ ale_linters#javascript#standard#GetCommand(bufnr(''))
+
+Execute(The global executable should be used otherwise):
+  AssertEqual
+  \ 'standard',
+  \ ale_linters#javascript#standard#GetExecutable(bufnr(''))
+
+  AssertEqual
+  \ ale#Escape('standard') . ' --stdin %s',
+  \ ale_linters#javascript#standard#GetCommand(bufnr(''))
+
+Execute(The global executable should be configurable):
+  let b:ale_javascript_standard_executable = 'foobar'
+
+  AssertEqual
+  \ 'foobar',
+  \ ale_linters#javascript#standard#GetExecutable(bufnr(''))
+
+  AssertEqual
+  \ ale#Escape('foobar') . ' --stdin %s',
+  \ ale_linters#javascript#standard#GetCommand(bufnr(''))
+
+Execute(The options should be configurable):
+  let b:ale_javascript_standard_options = '--wat'
+
+  AssertEqual
+  \ ale#Escape('standard') . ' --wat --stdin %s',
+  \ ale_linters#javascript#standard#GetCommand(bufnr(''))