slimlint: Search for .rubocop.yml and use it

This fixes slim-lint not honoring a `.rubocop.yml` in the file's or
parent directory. Due to the way slim-lint calls rubocop, it requires
the special `SLIM_LINT_RUBUCOP_CONF` env var to pick up the
`.rubocop.yml` if it is not run on the real file (which is the case
here).

See https://github.com/sds/slim-lint/blob/master/lib/slim_lint/linter/README.md#rubocop

ale_linters/slim/slimlint.vim

@@ -1,5 +1,25 @@
 " Author: Markus Doits - https://github.com/doits
-" Description: slim-lint for Slim files, based on hamllint.vim
+" Description: slim-lint for Slim files
+
+function! ale_linters#slim#slimlint#GetCommand(buffer) abort
+    let l:command = 'slim-lint %t'
+
+    let l:rubocop_config = ale#path#FindNearestFile(a:buffer, '.rubocop.yml')
+
+    " Set SLIM_LINT_RUBUCOP_CONF variable as it is needed for slim-lint to
+    " pick up the rubocop config.
+    "
+    " See https://github.com/sds/slim-lint/blob/master/lib/slim_lint/linter/README.md#rubocop
+    if !empty(l:rubocop_config)
+      if ale#Has('win32')
+        let l:command = 'set SLIM_LINT_RUBUCOP_CONF=' . ale#Escape(l:rubocop_config) . ' && ' . l:command
+      else
+        let l:command = 'SLIM_LINT_RUBUCOP_CONF=' . ale#Escape(l:rubocop_config) . ' ' . l:command
+      endif
+    endif
+
+    return l:command
+endfunction
 
 function! ale_linters#slim#slimlint#Handle(buffer, lines) abort
     " Matches patterns like the following:
@@ -21,6 +41,6 @@ endfunction
 call ale#linter#Define('slim', {
 \   'name': 'slimlint',
 \   'executable': 'slim-lint',
-\   'command': 'slim-lint %t',
+\   'command_callback': 'ale_linters#slim#slimlint#GetCommand',
 \   'callback': 'ale_linters#slim#slimlint#Handle'
 \})

test/command_callback/test_slimlint_command_callback.vader

@@ -0,0 +1,35 @@
+Before:
+  runtime ale_linters/slim/slimlint.vim
+
+  let g:default_command = 'slim-lint %t'
+
+  call ale#test#SetDirectory('/testplugin/test/command_callback')
+
+After:
+  Restore
+
+  unlet! g:default_command
+
+  let g:ale_has_override = {}
+
+  call ale#linter#Reset()
+  call ale#test#RestoreDirectory()
+
+Execute(The default command should be correct):
+  AssertEqual g:default_command, ale_linters#slim#slimlint#GetCommand(bufnr(''))
+
+Execute(The command should have the .rubocop.yml prepended as an env var if one exists):
+  call ale#test#SetFilename('../slimlint-test-files/subdir/file.slim')
+
+  AssertEqual
+  \ 'SLIM_LINT_RUBUCOP_CONF=''/testplugin/test/slimlint-test-files/.rubocop.yml'' ' . g:default_command,
+  \ ale_linters#slim#slimlint#GetCommand(bufnr(''))
+
+Execute(The command should have the .rubocop.yml prepended as an env var if one exists on win32):
+  call ale#test#SetFilename('../slimlint-test-files/subdir/file.slim')
+
+  let g:ale_has_override['win32'] = 1
+
+  AssertEqual
+  \ 'set SLIM_LINT_RUBUCOP_CONF=''/testplugin/test/slimlint-test-files/.rubocop.yml'' && ' . g:default_command,
+  \ ale_linters#slim#slimlint#GetCommand(bufnr(''))