diff --git a/ale_linters/haml/hamllint.vim b/ale_linters/haml/hamllint.vim
index b1a6aa5..e56da09 100644
--- a/ale_linters/haml/hamllint.vim
+++ b/ale_linters/haml/hamllint.vim
@@ -1,6 +1,31 @@
-" Author: Patrick Lewis - https://github.com/patricklewis
+" Author: Patrick Lewis - https://github.com/patricklewis, thenoseman - https://github.com/thenoseman
 " Description: haml-lint for Haml files
 
+function! ale_linters#haml#hamllint#GetCommand(buffer) abort
+    let l:prefix = ''
+
+    let l:rubocop_config_file_path = ale#path#FindNearestFile(a:buffer, '.rubocop.yml')
+    let l:hamllint_config_file_path = ale#path#FindNearestFile(a:buffer, '.haml-lint.yml')
+
+    " Set HAML_LINT_RUBOCOP_CONF variable as it is needed for haml-lint to
+    " pick up the rubocop config.
+    "
+    " See https://github.com/brigade/haml-lint/blob/master/lib/haml_lint/linter/rubocop.rb#L89
+    "     HamlLint::Linter::RuboCop#rubocop_flags
+    if !empty(l:rubocop_config_file_path)
+      if ale#Has('win32')
+        let l:prefix = 'set HAML_LINT_RUBOCOP_CONF=' . ale#Escape(l:rubocop_config_file_path) . ' &&'
+      else
+        let l:prefix = 'HAML_LINT_RUBOCOP_CONF=' . ale#Escape(l:rubocop_config_file_path)
+      endif
+    endif
+
+    return (!empty(l:prefix) ? l:prefix . ' ' : '')
+    \ . 'haml-lint'
+    \ . (!empty(l:hamllint_config_file_path) ? ' --config ' . ale#Escape(l:hamllint_config_file_path) : '')
+    \ . ' %t'
+endfunction
+
 function! ale_linters#haml#hamllint#Handle(buffer, lines) abort
     " Matches patterns like the following:
     " <path>:51 [W] RuboCop: Use the new Ruby 1.9 hash syntax.
@@ -21,6 +46,6 @@ endfunction
 call ale#linter#Define('haml', {
 \   'name': 'hamllint',
 \   'executable': 'haml-lint',
-\   'command': 'haml-lint %t',
+\   'command_callback': 'ale_linters#haml#hamllint#GetCommand',
 \   'callback': 'ale_linters#haml#hamllint#Handle'
 \})
diff --git a/test/command_callback/test_haml_hamllint_command_callback.vader b/test/command_callback/test_haml_hamllint_command_callback.vader
new file mode 100644
index 0000000..68aa1e6
--- /dev/null
+++ b/test/command_callback/test_haml_hamllint_command_callback.vader
@@ -0,0 +1,72 @@
+Before:
+  runtime ale_linters/haml/hamllint.vim
+
+  let g:default_command = 'haml-lint %t'
+  call ale#test#SetDirectory('/testplugin/test/command_callback')
+
+After:
+  Restore
+
+  unlet! g:default_command
+  unlet! b:conf
+
+  call ale#linter#Reset()
+  call ale#test#RestoreDirectory()
+
+Execute(The default command should be correct):
+  AssertEqual g:default_command, ale_linters#haml#hamllint#GetCommand(bufnr(''))
+
+Execute(The command should have the .rubocop.yml prepended as an env var if one exists):
+  call ale#test#SetFilename('../hamllint-test-files/rubocop-yml/subdir/file.haml')
+  let b:conf = ale#path#Winify(g:dir . '/../hamllint-test-files/rubocop-yml/.rubocop.yml')
+
+  if has('win32')
+    " Windows uses 'set var=... && command'
+    AssertEqual
+    \ 'set HAML_LINT_RUBOCOP_CONF='
+    \   . ale#Escape(b:conf)
+    \   .  ' && ' . g:default_command,
+    \ ale_linters#haml#hamllint#GetCommand(bufnr(''))
+  else
+    " Unix uses 'var=... command'
+    AssertEqual
+    \ 'HAML_LINT_RUBOCOP_CONF='
+    \   . ale#Escape(b:conf)
+    \   .  ' ' . g:default_command,
+    \ ale_linters#haml#hamllint#GetCommand(bufnr(''))
+  endif
+
+Execute(The command should have the nearest .haml-lint.yml set as --config if it exists):
+  call ale#test#SetFilename('../hamllint-test-files/haml-lint-yml/subdir/file.haml')
+  let b:conf = ale#path#Winify(g:dir . '/../hamllint-test-files/haml-lint-yml/.haml-lint.yml')
+
+  AssertEqual
+  \ 'haml-lint --config '
+  \   . ale#Escape(b:conf)
+  \   . ' %t',
+  \ ale_linters#haml#hamllint#GetCommand(bufnr(''))
+
+Execute(The command should include a .rubocop.yml and a .haml-lint if both are found):
+  call ale#test#SetFilename('../hamllint-test-files/haml-lint-and-rubocop/subdir/file.haml')
+  let b:conf_hamllint = ale#path#Winify(g:dir . '/../hamllint-test-files/haml-lint-and-rubocop/.haml-lint.yml')
+  let b:conf_rubocop = ale#path#Winify(g:dir . '/../hamllint-test-files/haml-lint-and-rubocop/.rubocop.yml')
+
+  if has('win32')
+    " Windows uses 'set var=... && command'
+    AssertEqual
+    \ 'set HAML_LINT_RUBOCOP_CONF='
+    \   . ale#Escape(b:conf_rubocop)
+    \   .  ' && haml-lint --config '
+    \   . ale#Escape(b:conf_hamllint)
+    \   .  ' %t',
+    \ ale_linters#haml#hamllint#GetCommand(bufnr(''))
+  else
+    " Unix uses 'var=... command'
+    AssertEqual
+    \ 'HAML_LINT_RUBOCOP_CONF='
+    \   . ale#Escape(b:conf_rubocop)
+    \   .  ' haml-lint --config '
+    \   . ale#Escape(b:conf_hamllint)
+    \   .  ' %t',
+    \ ale_linters#haml#hamllint#GetCommand(bufnr(''))
+  endif
diff --git a/test/hamllint-test-files/haml-lint-and-rubocop/subdir/file.haml b/test/hamllint-test-files/haml-lint-and-rubocop/subdir/file.haml
new file mode 100644
index 0000000..e69de29
diff --git a/test/hamllint-test-files/haml-lint-yml/subdir/file.haml b/test/hamllint-test-files/haml-lint-yml/subdir/file.haml
new file mode 100644
index 0000000..e69de29
diff --git a/test/hamllint-test-files/rubocop-yml/subdir/file.haml b/test/hamllint-test-files/rubocop-yml/subdir/file.haml
new file mode 100644
index 0000000..e69de29