From 1d321e6f39eb0baef1d787eacbbb65700e82859e Mon Sep 17 00:00:00 2001
From: s-ol <s-ol@users.noreply.github.com>
Date: Wed, 12 Oct 2016 15:43:29 +0200
Subject: [PATCH] add luacheck linter

---
 ale_linters/lua/luacheck.vim | 48 ++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 ale_linters/lua/luacheck.vim

diff --git a/ale_linters/lua/luacheck.vim b/ale_linters/lua/luacheck.vim
new file mode 100644
index 0000000..11638ad
--- /dev/null
+++ b/ale_linters/lua/luacheck.vim
@@ -0,0 +1,48 @@
+" Author: Sol Bekic https://github.com/s-ol
+" Description: luacheck linter for lua files
+
+if exists('g:loaded_ale_linters_lua_luacheck')
+    finish
+endif
+
+let g:loaded_ale_linters_lua_luacheck = 1
+
+let g:ale_lua_luacheck_executable =
+\   get(g:, 'ale_lua_luacheck_executable', 'luacheck')
+
+function! ale_linters#lua#luacheck#Handle(buffer, lines)
+    " Matches patterns line the following:
+    "
+    " artal.lua:159:17: (W111) shadowing definition of loop variable 'i' on line 106
+    " artal.lua:182:7: (W213) unused loop variable 'i'
+    let l:pattern = '^.*:\(\d\+\):\(\d\+\): (\([WE]\)\d\+) \(.\+\)$'
+    let l:output = []
+
+    for l:line in a:lines
+        let l:match = matchlist(l:line, l:pattern)
+
+        if len(l:match) == 0
+            continue
+        endif
+
+        " vcol is Needed to indicate that the column is a character.
+        call add(l:output, {
+        \   'bufnr': a:buffer,
+        \   'lnum': l:match[1] + 0,
+        \   'vcol': 0,
+        \   'col': l:match[2] + 0,
+        \   'text': l:match[4],
+        \   'type': l:match[3],
+        \   'nr': -1,
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('lua', {
+\   'name': 'luacheck',
+\   'executable': g:ale_lua_luacheck_executable,
+\   'command': g:ale_lua_luacheck_executable . ' --formatter plain --codes --filename %s -',
+\   'callback': 'ale_linters#lua#luacheck#Handle',
+\})