From 08ed282ac84669abbc9c65dd1c43aaf7a96e0de1 Mon Sep 17 00:00:00 2001
From: w0rp <devw0rp@gmail.com>
Date: Tue, 13 Sep 2016 22:23:37 +0100
Subject: [PATCH] Add a linter rule for Python code.

---
 ale_linters/python/flake8.vim | 46 +++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 ale_linters/python/flake8.vim

diff --git a/ale_linters/python/flake8.vim b/ale_linters/python/flake8.vim
new file mode 100644
index 0000000..4850f8e
--- /dev/null
+++ b/ale_linters/python/flake8.vim
@@ -0,0 +1,46 @@
+if exists('g:loaded_ale_linters_python_flake8')
+    finish
+endif
+
+let g:loaded_ale_linters_python_flake8 = 1
+
+function! ale_linters#python#flake8#Handle(lines)
+    " Matches patterns line the following:
+    "
+    " stdin:6:6: E111 indentation is not a multiple of four
+    let pattern = '^stdin:\(\d\+\):\(\d\+\): \([^ ]\+\) \(.\+\)$'
+    let output = []
+
+    for line in a:lines
+        let l:match = matchlist(line, pattern)
+
+        if len(l:match) == 0
+            continue
+        endif
+
+        let line = l:match[1] + 0
+        let column = l:match[2] + 0
+        let code = l:match[3]
+        let text = l:match[4]
+        let type = code[0] ==# 'E' ? 'E' : 'W'
+
+        " vcol is Needed to indicate that the column is a character.
+        call add(output, {
+        \   'bufnr': bufnr('%'),
+        \   'lnum': line,
+        \   'vcol': 0,
+        \   'col': column,
+        \   'text': text,
+        \   'type': type,
+        \   'nr': -1,
+        \})
+    endfor
+
+    return output
+endfunction
+
+call ALEAddLinter('python', {
+\   'executable': 'flake8',
+\   'command': 'flake8 -',
+\   'callback': 'ale_linters#python#flake8#Handle',
+\})